From 115efe92ddd63a31332ca740d76eaf889a9c79ed Mon Sep 17 00:00:00 2001
From: Peter Mikkelsen <petermikkelsen10@gmail.com>
Date: Tue, 28 Jun 2022 01:11:58 +0200
Subject: problem 54

---
 problem54.ijs | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 problem54.ijs

(limited to 'problem54.ijs')

diff --git a/problem54.ijs b/problem54.ijs
new file mode 100644
index 0000000..1ea9083
--- /dev/null
+++ b/problem54.ijs
@@ -0,0 +1,41 @@
+trans =: {{(0,~2+i.17){~'23456789TJQKAHDSC'i.y}}
+
+split =: {{<"1 y$~(x%~#y),x}}
+
+read =: {{2 split 5 split 2 split (#~0~:]) trans fread y}}
+
+score =: monad define
+	'values suits' =. |:>>y
+	order =. \:values
+	suits =. order{suits
+	values =. order{values
+	'counts pairvals' =. |:\:~{{(#y),{.y}}/.~values
+	usuits =. ~.suits NB. unique suits
+	consecs =. 5<&|.\2+i.13
+	if. (1=#usuits)*.values-:10 11 12 13 14 do.
+		type =. 10 NB. Royal flush
+	elseif. (1=#usuits)*.(<values) e. consecs do.
+		type =. 9 NB. Straight flush
+	elseif. counts -: 4 1 do.
+		type =. 8,{.pairvals NB. Four of a kind
+	elseif. counts -: 3 2 do.
+		type =. 7,2{.pairvals NB. Full house
+	elseif. 1=#usuits do.
+		type =. 6 NB. Flush
+	elseif. (<values) e. consecs do.
+		type =. 5 NB. Straight
+	elseif. counts -: 3 1 1 do.
+		type =. 4,{.pairvals NB. Three of a kind
+	elseif. counts -: 2 2 1 do.
+		type =. 3,\:~2{.pairvals NB. Two pairs
+	elseif. counts -: 2 1 1 1 do.
+		type =. 2,{.pairvals NB. One pair
+	else.
+		type =. 1 NB. High card
+	end.
+	type,values
+)
+
+winner =: {{{.\:score"0>y}}
+
+problem54 =: +/0=winner"0 read 'p054_poker.txt'
\ No newline at end of file
-- 
cgit v1.2.3